Распространение агентов через Kaspersky Security Center

Распространение агентов на конечные устройства с помощью Kaspersky Security Center (KSC) состоит из следующих этапов:

Подготовка сервера KSC

Для распространения агентов через Kaspersky Security Center необходимо иметь настроенный сервер KSC с подключенными к нему устройствами.

Настройку сервера необходимо выполнять с помощью ИТ-службы вашей организации.

Установка агента на устройства

Чтобы выполнить установку агента на конечных устройствах с помощью консоли управления KSC, необходимо создать инсталляционный пакет с установщиком агента:

  1. Откройте консоль управления KSC.

  2. Перейдите в раздел Дополнительно → Удаленная установка → Инсталляционные пакеты.

  3. Нажмите на кнопку Создать инсталляционный пакет.

  4. Укажите файл установки агента.

    Особенности настройки инсталляционного пакета в зависимости от ОС:

    • Если установка производится в ОС Linux, то необходимо учитывать, что для разных семейств дистрибутивов предусмотрены разные установочные файлы, например, .rpm или .deb.

    • Если установка производится в ОС Windows, необходимо указать параметр запуска исполняемого файла:

      /q

Подготовка скрипта для настройки и запуска агента

Для автоматической настройки конфигурации и запуска агента необходимо создать инсталляционный пакет со скриптом. Рекомендуется использовать метод с применением скрипта, который подменяет параметры конфигурации.

Чтобы настроить автоматическую конфигурацию:

  1. Создайте скрипт в зависимости от ОС на конечных устройствах:

    • Windows

    • Linux

    • macOS

    Создайте BAT-скрипт со следующим содержимым:

    @echo off
    setlocal ENABLEDELAYEDEXPANSION
    
    :: === Настройки. ===
    set "CONF_PATH=C:\Program Files (x86)\RVision\Agent\etc\rpoint.conf"
    set "TMP_PATH=%CONF_PATH%.tmp"
    set "BACKUP_PATH=%CONF_PATH%.bak"
    
    :: === Новый URL. ===
    set "NEW_URL=nats://<address>:<port>"
    
    :: === Поиск подстроки. ===
    set "TARGET_SUBSTR=none"
    
    :: === Проверка наличия файла. ===
    if not exist "%CONF_PATH%" (
        echo [ERROR] Config not found: "%CONF_PATH%"
        exit /b 1
    )
    
    :: === Создание резервной копии. ===
    copy /Y "%CONF_PATH%" "%BACKUP_PATH%" >nul
    if not "%errorlevel%"=="0" (
        echo [ERROR] Failed to create backup: "%BACKUP_PATH%"
        exit /b 1
    )
    
    :: === Создание пустого временного файла. ===
    break > "%TMP_PATH%"
    set "REPLACED_COUNT=0"
    
    :: === Чтение файла rpoint.conf построчно и замена URL. ===
    for /f "usebackq delims=" %%L in ("%CONF_PATH%") do (
        set "LINE=%%L"
        rem Проверка наличия целевой подстроки в строке.
        echo(!LINE! | findstr /C:"%TARGET_SUBSTR%" >nul
        if not errorlevel 1 (
            rem Замена значения URL без изменения структуры строки.
            set "MOD_LINE=!LINE:%TARGET_SUBSTR%=%NEW_URL%!"
            >>"%TMP_PATH%" echo(!MOD_LINE!
            set /a REPLACED_COUNT+=1
        ) else (
            >>"%TMP_PATH%" echo(!LINE!
        )
    )
    
    :: === Проверка успешности выполнения замены. ===
    if "!REPLACED_COUNT!"=="0" (
        echo [ERROR] Target URL not found, config not modified.
        del "%TMP_PATH%" >nul 2>&1
        exit /b 2
    )
    
    :: === Применение обновленного файла конфигурации. ===
    copy /Y "%TMP_PATH%" "%CONF_PATH%" >nul
    if not "%errorlevel%"=="0" (
        echo [ERROR] Failed to overwrite "%CONF_PATH%"
        del "%TMP_PATH%" >nul 2>&1
        exit /b 1
    )
    del "%TMP_PATH%" >nul 2>&1
    
    :: === Запуск агента, опционально. ===
    "C:\Program Files (x86)\RVision\Agent\bin\rpoint-launcher.exe" restart
    echo Done. Replaced %REPLACED_COUNT% line(s). Backup saved as "%BACKUP_PATH%".
    endlocal
    exit /b 0

    Создайте bash-скрипт со следующим содержимым:

    #!/bin/bash
    set -e
    
    # === Путь к конфигурационному файлу. ===
    CONF_PATH="/opt/rvision/agent/etc/rpoint.conf"
    
    # === Новый URL для leafnodes. ===
    NEW_URL="nats://<address>:<port>"
    
    # === Проверка существования конфигурационного файла. ===
    if [ ! -f "$CONF_PATH" ]; then
     echo "Config file not found: $CONF_PATH"
     exit 1
    fi
    
    # === Замена URL в секции leafnodes. ===
    sed -i '/"leafnodes"/,/\]/{s#"url":[[:space:]]*"[^"]*"#"url": "'"$NEW_URL"'"#}' "$CONF_PATH"
    
    # === Запуск агента. ===
    /opt/rvision/agent/bin/rpoint-launcher start
    
    echo "Конфигурация обновлена и агент запущен."

    Создайте bash-скрипт со следующим содержимым:

    #!/bin/bash
    set -e
    
    # === Путь к конфигурационному файлу. ===
    CONF_PATH="/Library/R-Vision/agent/etc/rpoint.conf"
    
    # === Новый URL для leafnodes. ===
    NEW_URL="nats://<address>:<port>"
    
    # === Замена URL в секции leafnodes. ===
    sed -i '' '/"leafnodes"/,/\]/{s#"url":[[:space:]]*"[^"]*"#"url": "'"$NEW_URL"'"#}' "$CONF_PATH"
    
    # === Запуск агента. ===
    /Library/R-Vision/agent/bin/rpoint-launcher start
    
    echo "Конфигурация обновлена и агент запущен."

    Здесь:

    • <address> — адрес подключения к шлюзу.

    • <port> — порт подключения к шлюзу.

    Если используется TLS-соединение, вместо nats:// необходимо указать tls://.
  2. Откройте консоль управления KSC.

  3. Перейдите в раздел Дополнительно → Удаленная установка → Инсталляционные пакеты.

  4. Нажмите на кнопку Создать инсталляционный пакет.

  5. Укажите файл созданного скрипта.

Была ли полезна эта страница?

Обратная связь